Die Programmierung erfolgt dabei in der bekannten IDE des Arduino mit Hilfe des Arduino Uno als ISP. Ein In-System-Programmierung, auch bekannt als In-Circuit Serial Programming (ICSP) ist eine Hardware, mit deren Hilfe ein Mikrocontroller programmiert werden kann. Der folgende Sketch wird entsprechend den Ausführungen zum minimalen Blink übertragen.

Nach Einbindung der Software-Schnittstelle zur seriellen Kommunikation über die Leitungen RX/TX mit Pin 5 un 6 folgen die Festlegungen der Kommando-Bytes des emulierten Interfaces. Als Analogeingänge dienen Pin 2 und 3. Der einzige Digitalausgang kann über Pin 7 gesteuert werden. Um den Digitaleingang an Pin 1 zu benutzen müsste noch eine sogenannte Fuse geändert werden, was hier jedoch nicht erfolgt. Die Hauptschleife erwartet ein Kommando vom PC und reagiert entsprechend.

#include <SoftwareSerial.h>

//CLAB Commands
#define AIN1 60
#define AIN2 58
#define DIN 211
#define DOUT 81

//ATTINY85 Pins
#define portDIN   5     //PB5 Pin 1: reset! (fuse)
#define portAIN1  3     //PB3 Pin 2: ADC3
#define portAIN2  2     //PB4 Pin 3: ADC2
                        //GND Pin 4: GND
#define RX        0     //PB0 Pin 5: Receive Serial
#define TX        1     //PB1 Pin 6: Send Serial
#define portDOUT  2     //PB2 Pin 7: Bit 0 DOUT
                        //VCC Pin 8: 5V

SoftwareSerial Serial(RX, TX); 

void setup()
{ Serial.begin(9600);         //Special CLAB
  pinMode(portDOUT,OUTPUT);   
  pinMode(portDIN, INPUT);    //fuse to use
  digitalWrite(portDIN,HIGH); //PULLUP 
}

void loop()
{ int i, val, inbyte; byte b;
  val = Serial.available(); //Was da?
  if (val>0)
  {inbyte=Serial.read(); //abholen
   delay(5);
   switch(inbyte)
  { case 13  : //CLAB ID nur ab Compact 1.75!
               Serial.write(3);delay(2); //ID
               break;
    case DIN : Serial.write(digitalRead(portDIN));
               break; 
    case AIN1: Serial.write(analogRead(portAIN1)>>2);
               break;
    case AIN2: Serial.write(analogRead(portAIN2)>>2);
               break;
    case DOUT: digitalWrite(portDOUT,Serial.read());
               break;
  }
 }
 delay(10);
}