Die Klassische Mechanik liefert die Formel der Geschwindigkeit beim 'Freien Fall':

Bei einer Fallhöhe h von 0,7 m und der mittleren Fallbeschleunigung g = 9,81 ms^-2 berechnet sich die Geschwindigkeit zu:

Ausgehend von einem ganzzahligen Messergebnis können Werte zwischen 12 und 14 km/h noch im gültigen Bereich liegen. Hier könnte der Sketch umformuliert werden, um die Geschwindigkeit mit Nachkommastellen und in m/s an zu geben.

Rechts unten kann am roten Potentiometer die Verstärkung eingestellt werden.

Der Sketch und der Aufbau für den Arduino werden etwas modifiziert, um eine bessere Triggerung zu erreichen. Das Listing ist unten angegeben. Der praktische Aufbau erfolgt nach gegebener schamatischer Skizze, die Verschaltung entsprechend dem Sketch.

Die Einstellung der Verstärkung bzw. der Empfindlichkeit am Verstärker kann durch kurze Handbewegungen erfolgen. Die LED am Arduino leuchtet bei Messbereitschaft, also ohne Triggerauslösung. Das Potentiometer ist so einzustellen, dass im Ruhezustand noch gerade keine Messung ausgelöst wird. Nun kann die Anordnung positioniert werden und eine Probemessung erfolgen.

Die Frucht wird entweder auf Höhe der Tischkante einfach losgelassen (ohne den Arduino zu treffen) oder sie wird über den Rand gerollt, so dass eine Art schiefer Wurf entsteht. Auch dabei ist die Fallzeit, sowie die Fallgeschwindigkeit trotz Parabelbahn laut Theorie ja gleich.

Als Verstärker ist ein Zweifach-Operationsverstärker verbaut, die einzelnen Stufen sind als invertierender Verstärker ausgelegt, wobei eine Stufe regelbar ist. Durch einen Spannungsteiler wird das Bezugspotenzial auf die halbe unipolare Betriebsspannung gelegt. Der Vorteil ist der Verzicht auf negatives Potenzial, der Nachteil scheint zunächst der für Digitaleingänge ungünstige Ruhepegel von 2,5 Volt zu sein. Wird ein Arduino (o.ä) eingesetzt, gilt diese Einschränkung nicht. Hat der Digitaleingang nur eine Schaltschwelle, so hat der Analogeingang mit 10-Bit-Auflösung 1024 Triggerschwellen. Aus diesem Grund wird nicht mehr digital, sondern analog ausgelöst. Wird nun der bisherige Digitaleingang (Pin 7) zusätzlich mit Analogeingang A0 verbunden, ist hoch auflgelöstes Triggern möglich, mit jeweils 512 Stufen oberhalb und unterhalb des Ruhepegels. Die Triggerschwelle ist im Sketch fest auf den Wert 30 eingestellt. Wird dieser Wert unterschritten, beginnt die Messfolge.

#define TRIGGER_IN A0
#define TRIGGER_LEVEL 30
#define RADAR_IN 7
#define RADAR_OUT 13
#define SCANS 8 
int trigger;

Der Deklarationsteil zeigt die Konstanten und eine Variable für den neuen Trigger. Der Ausgang RADAR_OUT zeigt die Unruhe am Verstärkerausgang. Ein PWM-Ausgang (Pin 5) würde ein quasi analoges Signal an einer LED ausgeben. Hier wird lediglich die eingebaute LED an Pin 13 benutzt.

Die Triggerung in der Hauptschleife sieht nun so aus:

 ...
 Serial.println("ready");  // Trigger;
 do
 {trigger=analogRead(TRIGGER_IN);
  analogWrite(RADAR_OUT, map(trigger, 0, 1023, 0, 255));
 }
 while(trigger>TRIGGER_LEVEL);
 analogWrite(RADAR_OUT,0);
 ...

Die do-while-Schleife wartet, bis die Triggerschwelle unterschritten ist. Dabei wird der momentane Analogwert vom Verstärker als Arduino-"Analogwert" einer LED an Pin RADAR_OUT zugeführt. Vor Beginn der Messung wird sie ausgeschaltet.

Der Sketch für die Radarfalle - den Radarfall:

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

/*
 Radar-Sensor RSM-1650 24 GHz
 Verstärkung ca. 60 dB
 Gibt die Geschwindigkeit v
 mit zwei Nachkommastellen aus,
 wenn 44 Hz 1 km/h entsprechen. 
*/
#define TRIGGER_IN A0
#define TRIGGER_LEVEL 30
#define RADAR_IN 7
#define RADAR_OUT 13
#define SCANS 8 
int trigger;
double v,vmax;

void setup() 
{ Serial.begin(9600);
  pinMode(RADAR_IN,INPUT);
  pinMode(RADAR_OUT,OUTPUT);
  pinMode(TRIGGER_IN,INPUT);
}

void loop() 
{unsigned long T;            // Periodendauer in us
 double f;                   // Frequenz in MHz 
 vmax=0;                     // 
 Serial.println("ready");    // Trigger;
 do
 {trigger=analogRead(TRIGGER_IN);
  analogWrite(RADAR_OUT, map(trigger, 0, 1023, 0, 255));
 }
 while(trigger>TRIGGER_LEVEL);
 analogWrite(RADAR_OUT,0);
 for(int i=0;i<SCANS;i++)    // 8 Messungen 
 {T = pulseIn(RADAR_IN, HIGH) + pulseIn(RADAR_IN, LOW);
  f=1/(double)T;             // f=1/T   
  v=((f*1e6)/44.0);          // 24 GHz Radar
  vmax=max(v,vmax);          // Schleppzeiger
  Serial.print(">");         // 16 Punkte (LCD)
 } 
 Serial.print(vmax,2);Serial.println(" km/h");
 delay(2000);                // 2 Sekunden
}

Eine Kalibrierung im Sinne der Definition des Sensors fand hier nicht statt. Vielmehr wurde mit einem bekannten Wert verglichen, also eine Art Referenzmessung durchgeführt. Ungenauigkeiten tauchen eher bei der Programmierung oder dem realen mechanischen Aufbau auf. Die Genauigkeit dieser Anordnung dürfte für viele Fälle hoch genug sein. Gab es beim Verkehrsradar nicht auch 10% Toleranz?